ばっち。ばっちい。

server.bat

@ECHO OFF
setlocal

set zip="C:\Program Files\7-Zip\7z.exe"
set compress=compress.bat
set minecraft=craftbukkit-1.7.9-R0.3-SNAPSHOT_horse.jar

:RESTART

"%ProgramFiles%\Java\jre7\bin\java.exe" -Xincgc -Xmx16G -jar %minecraft%

echo "Minecraftサーバーデータのバックアップを開始します"
timeout 10

set backpath=d:\xxx
set dt=%date%
set FName=%backpath%\%dt:~-10,4%%dt:~-5,2%%dt:~-2,2%

IF EXIST %FName% GOTO SKIPBACK
IF EXIST %FName%.7z GOTO SKIPBACK
REM mkdir %FName%
mkdir %FName%\plugins

set x=%~dp0
set x=%x:~0,-1%

echo 秋祭りマップバックアップ...
for /D %%i in (aki_matsuri2013) do (
    echo %%i
    xcopy %%i /E %FName%\%%i\
)
echo 資源ENDバックアップ...
for /D %%i in (end*) do (
    xcopy %%i /E %FName%\%%i\
    echo %%i
)
echo ホームマップバックアップ...
for /D %%i in (home*) do (
    xcopy %%i /E %FName%\%%i\
    echo %%i
)
echo 資源ネザーバックアップ...
for /D %%i in (nether*) do (
    xcopy %%i /E %FName%\%%i\
    echo %%i
)
echo ゲームマップバックアップ...
for /D %%i in (pvp*) do (
    xcopy %%i /E %FName%\%%i\
    echo %%i
)
echo 資源MAPバックアップ...
for /D %%i in (shigen*) do (
    xcopy %%i /E %FName%\%%i\
    echo %%i
)
echo 基本ワールドバックアップ...
for /D %%i in (world*) do (
    xcopy %%i /E %FName%\%%i\
    echo %%i
)
xcopy プラグインデータバックアップ...
xcopy %x%\plugins\EcoGate\Gates.yml %FName%\plugins\
xcopy %x%\plugins\EcoGate\Worlds.yml %FName%\plugins\
xcopy %x%\plugins\ForumPlugin\command_reject.txt %FName%\plugins\
xcopy %x%\plugins\ForumPlugin\spawn_reject.txt %FName%\plugins\
xcopy %x%\plugins\ForumPlugin\bans.txt %FName%\plugins\
echo 掲載用に省略

echo バックアップ完了

set cmd=%compress% %zip% a %FName%.7z %FName%
echo "execcmd %cmd%"

start "" %cmd%
echo 7ZIP圧縮突き離し起動

goto PRE
:SKIPBACK
echo "Minecraftサーバーのバックアップをスキップしました"

:PRE
echo "Minecraftサーバーを再起動します"
timeout 10

goto RESTART


endlocal
exit

compress.bat

@ECHO OFF
setlocal

echo param1=%1
echo param2=%2
echo param3=%3
echo param4=%4

%1 %2 %3 %4

rmdir /s /q %4

endlocal
exit
user/ecolight/bat.txt · 最終更新: 2014/09/17 19:55 by えこライト